Chapitre 6 : Suites et séries 

1. Suites du type  

1.1 Composition d'opérateurs 

>	restart:f:=x->x+1/x;

 

 

L'opérateur  @@  représente l'application répétée de la composition d'opérateurs. 

 

>

f@@n;

 

 

>	u:=n->(f@@n)(5.);

 

 

>	u(6);(f@@6)(5);evalf(%);

 

 

 

 

>	(f@@7)(5.);(f@@7)(5);

 

 

 

>	u(999),u(1000),u(1001);

 

 

Donc il semble que la suite diverge 

1.2 Divergence 

On veut montrer qu'effectivement la suite précédente est divergente : 

>	limit((f@@n)(5.),n=infinity);

 

 

Donc la commande  limit ne donne rien. Il faut donc utiliser une autre méthode : 

>	g:=x->(f(x))^2-x^2;

 

 

>	expand(g(x));

 

 

>	sum(g(u(k)),k=0..m);

 

 

et donc ?. Donc la suite diverge.  

1.3 points fixes 

Étudier la suite définie par :  

>	f:=x->(1+x^2)/2;

 

 

Un point fixe doit vérifier f(x)=x : la commande fsolve donne ici une racine double : 

 

>	fsolve(f(x)=x,x);

 

 

>	factor(f(x)-x);

 

 

Ce carré montre que la suite est toujours croissante 

>	factor(f(x)-1);

 

 

Donc la suite converge pour  

1.4 Représentation graphique 

>	a:=1.75:M := NULL:for k to 5 do M := M,[a,a],[a,f(a)]:a := f(a): od: M;

 

 

>	plot([f,[M],x->x],0..5,0..5,color=black);

 

 

>	a:=-0.25:M := NULL: for k to 5 do M := M,[a,a],[a,f(a)]:a := f(a): od: M;

 

 

>	plot([f,[M],x->x],-1/3..1,-1/3..1,color=black);

 

 

1.5 Étude analogue pour la suite  

>	f:=x->exp(-x)/x;

 

 

Point fixe : 

>	alpha:=fsolve(f(x)=x,x);

 

 

La dérivée de f est obtenue par l'opérateur D: cette dérivée est toujours négative si x>0 : 

>

D(f);

 

 

Par le théorème des accroissements finis, on a : f(x)-f(alpha) = (x-alpha)D(f)(u), u étant un réel compris entre x et alpha. Ainsi,  f(x)-f(alpha) est toujours de signe opposé à  x-alpha. Et donc la suite saute alternativement de part et d'autre de alpha d'où le bel escargot suivant: 

 

>	a:=0.6:M := NULL: for k to 5 do M := M,[a,a],[a,f(a)]:a := f(a): od: M: plot([f,[M],x->x],0..3,0..3,color=black);

 

 

2. Suites du type  

2.1 Suite de Fibonacci :   

>	a:=1:b:=1:for k to 10 do c:=a+b:print(c):a:=b:b:=c:od:

 

 

 

 

 

 

 

 

 

 

 

2.2 Fonctions récursives 

Il est possible en Maple, comme en beaucoup d'autres langages (sauf en Fortran), de définir des fonctions récursives, c'est à dire des fonctions qui s'appellent elles-mêmes. Ici, par exemple, pour Fibonacci :  

 

>	fib:=n-> if n<=1 then n else fib(n-1)+fib(n-2);fi;

 

 

>	fib(11),fib(12);

 

 

La fonction trace montre le déroulement du calcul : 

>	trace(fib):fib(4);untrace(fib);

 

{--> enter fib, args = 4
{--> enter fib, args = 3
{--> enter fib, args = 2
{--> enter fib, args = 1 

 

<-- exit fib (now in fib) = 1}
{--> enter fib, args = 0 

 

<-- exit fib (now in fib) = 0} 

 

<-- exit fib (now in fib) = 1}
{--> enter fib, args = 1 

 

<-- exit fib (now in fib) = 1} 

 

<-- exit fib (now in fib) = 2}
{--> enter fib, args = 2
{--> enter fib, args = 1 

 

<-- exit fib (now in fib) = 1}
{--> enter fib, args = 0 

 

<-- exit fib (now in fib) = 0} 

 

<-- exit fib (now in fib) = 1} 

 

<-- exit fib (now at top level) = 3} 

 

 

Il y a eu 9 appels à la fonction fib. De façon générale, on montre qu'il y a 2 fib(n+1)-1 appels. Si on regarde attentivement le schéma ci-dessus, on voit qu'il y a plusieurs fois appel à fib(0),   fib(1) et fib(2) ; pour éviter ces répétitions, on utilisera comme ci-dessous, l'option remember. Il n'y a plus que 5 appels ! 

>	fib:=proc(n) option remember: if n<=1 then n else fib(n-1)+fib(n-2);fi;end;

 

 

2.3 Solution d'équation de récurrence avec rsolve 

Le terme général de la suite est obtenu à l'aide de la commande de solution d'équation de récurrence rsolve : 

>	restart:lapin:={f(n)=f(n-1)+f(n-2),f(1..2)=1};

 

 

>	sol:=rsolve(lapin,f);g:=unapply(factor(sol),n);

 

 

 

La commande evala donne une évaluation algébrique dans le champ algébrique le plus petit possible : 

>	evala(g(11)),evala(g(12));

 

 

2.4 La commande fibonacci 

>	combinat[fibonacci](11),combinat[fibonacci](12);

 

 

La commande fibonacci de la bibliothèque combinat  marche aussi pour des nombres négatifs et donne de plus les polynômes de Fibonacci. On peut obtenir le listing de cette fonction (comme 95% des fonctions de Maple) avec la variable  verboseproc mise à 2 : 

>	interface(verboseproc=2);print(combinat[fibonacci]):

 

 

 

2.5 Série Génératrice 

Les valeurs de , pour n grand, s'obtiennent  à l'aide de la série génératrice définie par .  La commande  ztrans  de Maple donne la transformée Z  de , c'est à dire , qui est toujours une fraction rationnelle dans le cas de récurrence linéaire à coefficients constants. Pour les nombres de Fibonacci, les commandes ci-dessous calculent successivement   avec les conditions initiales, puis . 

 

>	restart: rel := ztrans(u(n+2)=u(n+1)+u(n),n,z);

 

 

>	v := solve( rel, ztrans(u(n),n,z));

 

 

>	v := subs({u(0)=0,u(1)=1},v);

 

 

>	v := normal(subs(z=1/z,v));

 

 

>	solve(denom(v),z);

 

 

>	d:=factor(denom(v),sqrt(5));

 

 

>	v:=convert(-z/d,parfrac,z);

 

 

Ci-dessous, la plus petite racine en valeur absolue sera appelée a (ici a est l'inverse du nombre d'or) et on calculera le coefficient   qui lui est relatif. En développant en puissance de z le terme 1/(1-z/a), on obtiendra une approximation de et en particulier   sera approximé par a/ 

 

>	alpha:=-1/2+1/2*sqrt(5);

 

 

>	principal:=op(2,v); a:=subs(z=0,principal);

 

 

 

On doit remarquer que les coefficients en z du développement de Taylor ci-dessous donnent bien les nombres de Fibonacci, même pour des valeurs de n petites (n=9, 10, 11) : 

 

>	evalf(taylor(principal,z,12));

 

 

>	evalf(a/alpha^9),combinat[fibonacci](9); evalf(a/alpha^10),combinat[fibonacci](10);   evalf(a/alpha^11),combinat[fibonacci](11);

 

 

 

 

 

3. Développement asymptotique du reste d'une série 

3.1 Détermination numérique de α et ß 

Un développement asymptotique est un développement du type Pour m assez grand les termes correctifs sont de plus en plus petits. On cherche tout d'abord à déterminer par tatonnements a et ß : 

 

>	restart: f:=n->sum(1/k^2,k=1..n);

 

 

>	for p to 5 do m:=10^p:r1:=evalf((f(infinity)-f(m))*m):print(m,r1):od:

 

 

 

 

 

 

Donc α = 1 . 

>	f(infinity);

 

 

>	for p to 5 do m:=10^p:r2:=evalf((Pi^2/6-f(m)-1/m)*m^2):print(m,r2):od:

 

 

 

 

 

 

Donc α = 1 et ß = -0.5 

3.2 Détermination analytique de α et ß 

>	m:='m':1/k^2-z*(1/(k-1)-1/k);factor(1/k^2-z*(1/(k-1)-1/k));

 

 

 

Pour avoir un reste en 1/,  il faut que z = 1, c'est à dire α = 1. 

 

>	sum(z/(k*(k-1)),k=m+1..infinity);

 

 

>	sum(zz/(k*(k-1)*(k-2)),k=m+1..infinity);

 

 

Donc le terme en 1/ est -1/2. 

3.3 Détermination numérique des termes jusqu'au 7ème ordre 

>	Digits:=20:for p to 5 do m:=10^p:print(m,evalf((Pi^2/6-f(m)-1/m+1/(2*m^2))*m^3)) od:

 

 

 

 

 

 

Donc γ = 1/6. 

>	for p to 5 do m:=10^p:print(m,evalf((Pi^2/6-f(m)-1/m+1/(2*m^2)-1/(6*m^3))*m^4)):od:

 

 

 

 

 

 

Donc le terme en est égal à 0. 

>	Digits:=50: for p to 5 do m:=10^p:print(m,evalf((Pi^2/6-f(m)-1/m+1/(2*m^2)-1/(6*m^3))*m^5)):od:

 

 

 

 

 

 

Donc le terme en est égal à 1/30. 

>	for p to 5 do m:=10^p:print(m,evalf((Pi^2/6-f(m)-1/m+1/(2*m^2)-1/(6*m^3)+1/(30*m^5))*m^6)):od:

 

 

 

 

 

 

Donc le terme en est égal à 0. 

>	for p to 5 do m:=10^p:print(m,evalf((Pi^2/6-f(m)-1/m+1/(2*m^2)-1/(6*m^3)+1/(30*m^5))*m^7)):od:

 

 

 

 

 

 

En remarquant que le coefficient entier doit être 42.
En fait, la fonction asympt donne directement tous les résultats précédents !!! 

>	m:='m':asympt(f(infinity)-f(m),m,8);

 

 

4. Sommes partielles de séries numériques simples 

: factor(sum(i,i=1..n)); 

 

: factor(sum(i^2,i=1..n)); 

 

: factor(sum(i^3,i=1..n)); 

 

: factor(sum(3*i^2-3*i+1,i=1..n)); 

 

On cherche à déterminer le polynôme P(n) tel que :     

>	factor(sum(2*i - 1, i=1..n));

 

 

>	expand(sum(4*i^3 - 6*i^2 + 1, i=1..n));

 

 

>	expand(sum(4*i^3 - 6*i^2 + 4*i - 1, i=1..n));

 

 

>	expand(sum(5*i^4 - 10*i^3 + 10*i^2 - 5*i + 1, i=1..n));

 

 

>