Chap. 1 :Premiers pas 

1. Le démarrage 

 

 

 

 

Image 

2. Exemples d'opérations simples 

Pour commencer taper la somme de deux chiffres suivie d'un point-virgule, signe obligatoire de fin de commande. Le résultat ets donné en bleu au centre de la ligne suivante, comme indiqué ci-dessous :  

> 1 + 2;
 

3 

Peut-être que vous serez la première fois dérouté par la couleur noire de l'expression " 1 + 2 " comme montré dans l'image ci-dessous et des notations de fractions qui ne sont pas usuelles pour ceux qui ont travaillé avec des versions antérieures de Maple. En fait, il y a maintenant 2 styles d'entrées des données (input)  dans la version 10 de Maple : "2D Math-notation" et "Maple notation". Si ce que vous entrez apparaît en noir (encore une fois comme dans la figure ci-dessous), vous vous trouvez probablement dans le premier cas. Nous allons basculer dans la notation traditionnelle - celle qui sera toujours utilisée par la suite sauf spécification explicite - en allant dans le menu Tools, en prenant le sous menu Options ... 

Image 

en cliquant sur l'onglet Display puis Input Display et on bascule de "2D Math-notation" en "Maple notation". On termine en effectuant ce choix pour la session en cours de Maple  ou (et je vous le conseille pour la suite de ces chapitres) en choix permanent (Globally) qui sera appliqué chaque fois que vous ouvrirez Maple : vous n'aurez plus à refaire ces opérations de déclaration de la forme de l'input ! 

Image 

Après avoir donné le résultat, Maple affiche un prompt au début d'une nouvelle ligne indiquant qu'il attend la commande suivante. Maple remplace toujours la somme de deux fractions par le résultat sous forme rationnelle : 

> 3/4 + 8/9;
 

59/36 

L'approximation - décimale ou binaire ou sur toute autre base - d'un nombre est appelée nombre en virgule flottante ou simplement  flottant. Maple remplace toujours la somme d'une fraction avec un flottant par un  flottant : 

> 8/9+5.1;
 

5.988888889 

Le résultat est donc 5988888889/1000000000, approximation ici de 539/90. La précision par défaut est de 10 chiffres. Pour modifier cette précision, il faut changer la valeur d'une variable appelée Digits.Une valeur est donnée à une variable par le signe d'affectation :=, deux points suivis du signe égal. L'oubli de cette règle est souvent, au début, une erreur très fréquente : on a tendance en effet à confondre le signe d'affectation avec le signe d'égalité. Ainsi a := b et n'ont pas le même sens ! 

> Digits := 20;
 

20 

>  8/9 + 5.1 ;
 

5.9888888888888888889 

Ce résultat n'est pas identique au précédent : la commande evalb vérifie si l'égalité est vraie ou fausse : 

> evalb(5.988888889 = 5.9888888888888888889);
 

false 

Si on revient à une précision à 10 chiffres, l'égalité est par contre vérifiée : 

> Digits := 10;
evalb(5.988888889 = 5.9888888888888888889);
 

10 

true 

Il peut arriver de faire une erreur dans la frappe d'une commande comme, dans l'exemple ci-dessous, en tapant deux fois le signe somme : 

> 8/9 + + 5.1;
 

Error, `+` unexpected 

Maple signale tout de suite  l'erreur en plaçant le curseur | clignotant à l'endroit de l'erreur ou juste après. Simplement, corriger et relancer la commande. 

Les trois exemples qui suivent montrent que Maple donne la dérivée, ou la primitive ou l'intégrale d'expressions. Il faut toujours indiquer la variable par rapport à laquelle on dérive ou on intègre. 

> diff(x^4,x);
 

4*x^3 

> int(t^5, t);
 

1/6*t^6 

> int(t^5, t = a .. b);
 

1/6*b^6-1/6*a^6 

3. Graphiques à deux dimensions 

3.1 Le plus simple 

La méthode qui ne nécessite aucune connaissance des nombreuses commandes et options graphiques, consiste à écrire après un prompt une expression algébrique à une variable puis sur le résultat (l'output en bleu) faire un clic droit. On obtient un menu déroulant qui propose de nombreuses possibilités : intégrer, différentier, évaluer en un point, transformer en langage C, Fortran, etc.Dans ces propositions il y a Plots qui permet d'obtenir un tracé graphique en 2-D (l'option Plot Builder est présentée plus loin) de l'expression correspondante : 

 

> cos(x);
 

cos(x) 

Image 

On obtient le graphe de l'expression ici non labellisée (si les équations avaient été labellisées - c'est une des options possibles - le label serait apparu entre les parenthèses) : 

> smartplot( );
 

Plot 

 

3.2 En mode commande 

La commande plot produit une figure de l'expression donnée en premier argument. Un second argument peut préciser l'intervalle, sinon par défaut on a .  

 

> plot(cos(x)*exp(-x),x=0..5);
 

Plot 

Un clic droit dans le dessin permet d'accéder à de nombreuses options. Alternativement, un clic gauche  sur la figure modifie la barre des menus et les icônes qui apparaissent permettent de modifier une partie de la présentation de la figure. Ci-dessous ce qui est obtenu avec le clic droit : 

Image 

3.3 La méthode interactive 

On peut également préciser les options avant de tracer la figure : il faut d'abord charger la librairie plots par la commande with(plots) suivie de la commande interactive. La méthode du clic droit comme expliqué en 3.1 permet également d'atteindre Plot Builder. Une nouvelle fenêtre s'ouvre alors et qui montre les différentes possibilités offertes.  

Image 

Le bouton Options conduit à une deuxième fenêtre où un certain nombre de paramètres peuvent être modifiés :  

Image 

On termine par le dernier bouton en bas à droite qui donne la figure. Le désavantage de cette méthode est qu'il faut recommencer les deux tableaux si on veut modifier légèrement un paramètre. Il est préférable d'utiliser le bouton Command qui apparaît également à la dernière ligne et qui donne (output en bleu) la commande plot avec les paramètres qui ne prennent pas leur valeur par défaut. On copie à la souris (control+c) et on la met sur la ligne de commande suivante (control+v). Il est alors facile de modifier un paramètre quelconque, l'épaisseur (thickness) par exemple : 

> with(plots):
interactive(cos(x)*exp(-x));
 

plot(cos(x)*exp(-x), x = 0 .. 5, linestyle = DASHDOT, thickness = 3, title =
plot(cos(x)*exp(-x), x = 0 .. 5, linestyle = DASHDOT, thickness = 3, title =
 

> plot(cos(x)*exp(-x), x = 0. .. 5.0, linestyle = DASHDOT, thickness = 3, title = "cos x exp", titlefont = ([TIMES, BOLD, 12]));
 

Plot 

3.4 Obtenir toutes les options ... 

Aller dans Maple Help qui est très riche (control+F1) et demander "plot,options". La fenêtre de droite à fond jaune décrit toutes les options disponibles en 2-D. D'une manière générale les pages du help sont très bien faites et donnent en bas de page des exemples : le plus souvent on peut les regarder directement, on y trouve ce que l'on cherche. Mieux, il est possible de transformer une page de help en page de calcul en cliquant sur le 6ème bouton à partir de la gauche : les commandes en rouge peuvent alors être exécutées ou modifiées, ce qui permet rapidement de comprendre "comment ça marche" ! 

Image 

Avec toutes les options désirées (remarquer l'option view), deux courbes vont être superposées sur un même graphique à l'aide de la commande display de la bibliothèque plots. 

> courbe_1:=plot(cos(x)*exp(-0.2*x),
            x = -10 .. 10, thickness = 3, color = blue, scaling = unconstrained):
courbe_2 := plot(sin(2*x), x = -10 .. 10, linestyle = DOT, thickness = 2):
plots[display]({courbe_1, courbe_2}, title = "2 fonctions", titlefont = [TIMES, BOLD, 12],
            view=[-5..5,-2.0..1.2],axes=framed,tickmarks=[5, 6]);
 

Plot 

4. Graphiques en 3-D 

4.1 La commande 3d 

Pour obtenir un graphique en trois dimensions, on peut procéder par un menu déroulant comme dans les paragraphes 3.1 ou avec Plot Builder comme en 3.3. Ici, comme en 3.2, on utilise une commande, plot3d : 

> plot3d(sin(v)*sin(w),v=-Pi..Pi,w=-Pi..Pi, axes=boxed);
 

Plot 

En cliquant sur la figure, la barre de menus est changée : à partir de la gauche, les deux premiers boutons, et donnent l'orientation de la figure,  puis vient des options pour tracer les lignes de niveaux, puis un bouton offre différents types d'axes, le bouton 1:1 othonormalise les axes et enfin le dernier bouton à droite offre 3 choix : la main permet de déplacer le graphe dans la zone graphique, la flêche vers le bas permet d'agrandir ou diminuer le graphe et la dernière option, flêche vers la droite permet de faire pivoter la figure dans tous les sens, ce qui donne une bonne manière d'appréhender les figures dans l'espace ! 

Image 

Une fois de plus un clic droit sur la figure offre de nombreuses options : transparence, éclairage, etc 

4.2 Pour le fun : coquillages en 3 dimensions 

Pour terminer et pour montrer la puissance du graphisme en 3 dimensions, on donne cidessous une méthode pour dessiner une ammonite. Les commandes ont été obtenues au Maple Application Center ("it offers over 1,500 Maple applications, Maplet applications, tutorials, Maple PowerTools, Maple T.A. resources and Maple packages for free download" :  addresse http://www.maplesoft.com/applications/index.aspx ). Dans la rubrique Science/Biology on trouve l'application 3-D surface models of seashells qui donne de superbes dessins de 11 coquillages en 3 dimensions. Pour l'ammonite : 

On commence par une partie générale pour 11 coquillages. Les débutants pourront se contenter de copier les ordres à la souris (control+C, control+V), ces ordres étant parfaitement expliqués dans la page html référencée ci-dessus 

> restart:with(plots):
rad:=proc(aa) aa/360*2*Pi end:
x:=D*(A*sin(beta)*cos(Theta)+R*cos(s+phi)*cos(Theta+Omega)
  -R*sin(mu)*sin(s+phi)*sin(Theta+Omega))*exp(Theta*cot(alpha)):
y:=(-A*sin(beta)*sin(Theta)-R*cos(s+phi)*sin(Theta+Omega)
  -R*sin(mu)*sin(s+phi)*cos(Theta+Omega))*exp(Theta*cot(alpha)):
z:=(-A*cos(beta)+R*sin(s+phi)*cos(mu))*exp(Theta*cot(alpha)):

SR:=R=RE+k:
SRE:=RE=1/sqrt(cos(s)^2/a^2+sin(s)^2/b^2):
Sk:=k=L*exp(-(2*(s-P)/W[1])^2)*exp(-(2*g/W[2])^2):
Sg:=g=2*Pi/N*(Theta*N/2/Pi-round(Theta*N/2/Pi)):
 

Puis application à l'ammonite  

> S:={D=1,alpha=rad(83),beta=rad(90),phi=rad(1),mu=rad(1), Omega=rad(1),smM=rad(-170)..rad(170),A=2.5,a=1,b=0.9,P=10,W[1]=100,W[2]=20,N=15,L=1/2}:
R1:=simplify(subs(S,subs(SR,SRE,Sk,Sg,[x,y,z]))):
plot3d(R1,s=subs(S,smM),Theta=-1*Pi..4*Pi,grid=[40,60],style=patchnogrid,scaling=constrained,lightmodel=light2,shading=xyz,glossiness=1.0,projection=0.5,orientation=[-97,58]);
 

Plot 

En cliquant sur la figure avec le bouton gauche, on peut la faire tourner en trois dimensions. Avec le bouton droit, on peut choisir un grand nombre d'options, de couleurs, de quadrillage, d'axes, etc.
Ce programme a été écrit en 2001 sous Maple V. La figure - obtenue alors et légèrement différente - est reproduite ci-dessous :
 

Image